Arma3 Editing

Thought I would make a thread for anyone who is into making there own missions since there is not one at the moment, I'm currently in the early stages of making my own mission which will involve most of the map with multiple tasks as currently the missions on there are very short I'm trying to get it some what like the map missions where there are target areas and objectives but also patrolling contacts/sniper teams/air bourne and veh mounted enemy patrolling to keep everyone on there toes and stop it getting stale I'm completely new to the editing scene for arma literally started this afternoon however it reminds me a lot of the old wc3 editor which I was quite handy with back in the day I currently have a full village occupied by enemy forces with a.VIP kill task situated in the village and fireteam patrolling with a respawn script if anyone dies. Just a little heads up on my plans and is anyone else having a go at the editor?

Posted of my phone sorry for random dot and s**t I'm terrible at typing on this thing

I would if I had the editor and the patiance for it... I get too stressed doing everything then testing it and finding so many bugs that I gotta fix :3

I need a training map like Capitan's with choppers n' jets ooooo

Spent some time in the editor yesterday. Tried to make a convoy mission (destroy convoy) which worked a bit. I understand the editor a bit better now, I will definitely use it more.

Yeah it takes a while to get used to, spent 4 hours on it and got used to it a bit had some experience with scripts and setting triggers and conditions before with the wc3 editor so its not totally alien to me Im going to do some more advanced missions I want to get a clan game going on it

I love this editor.

didnt really try arma 2 editor but I couldnt be bothered with arma 2 editor

kerrermanisNL wrote:Spent some time in the editor yesterday. Tried to make a convoy mission (destroy convoy) which worked a bit. I understand the editor a bit better now, I will definitely use it more.

Did you manage to set it so you had to kill ALL enemy in the patrol? I have been having trouble setting kill tasks for multiple units want a clear village of enemy units task but have only manage to get it to work for single units

Yeah managed to get it for groups of enemy. You need to group them together and then place the trigger activation on "any member of group" (or something). The reasoning behind it is: if you put it on whole group, it means that when the whole group is no longer in the radius it triggers, which you don't want.

I'll look for the link I used, it was very informative and clear.

-Edit

Here it is:

There is a lot still the same like back in 2001. Although there are many improvements. The video is helping out a lot.

How to I empty the choppers (so there are no bots in them)?

Ah nice thanks for that kerrermanisNL just found this http://www.armaholic.com/forums.php?m=posts&p=3915#3915 forum its very helpful check Bracks post in particular its about halfway down a lot of nice scripts there

This might be handy for all you scripters out there:

http://community.bistudio.com/wiki/Category:Arma_3:_New_Scripting_Commands_List

Sorry Lovvi missed your post you will want to select ''empty'' then cars this way it will spawn just the car without ai which u can drive

Thanks

No problem I have a nice custom supply box script I wrote up last night I will link it when I'm home later should save a lot of time rather than doing it your self if anyone wants it

Just made first derpy TDM mission, should add a script that ends the mission after 30 kills or something, though I don't know how to execute scripts

Ah! I know this! I know. Mr. Teacher pick me! Pick me!

I asked on www.reddit.com/r/armadev about counting number og civilians deaths and someone gave me this answer: LINKY

Basically you can call a script from in the editor (say, a unit's INIT line or a triggers ON ACT line) like this: nul = [] execvm "script.sqf";

Alternatively if you go to \user\documents\arma3\missions you will find a folder with your mission in it (provided you saved it first). There you can create a new text file and change the appendix from .txt to .sqf and name it init.sqf. This file will be run automatically on mission start, so you can type the same thing as above (I think...) and it will run automatically.


About ending mission at 30 kills. Underneath is the init.sqf file from a mission I made where if you kill 3 civis the mission end. It's the same as linked to reddit but I removed the bit about killing a "General" unit. If you replace the civi counter with a counter for each faction, and add Event Handlers for units dying on both sides, you can have any kill limit you want.

Code:

// Current number of civilians
// the player has killed
deadCivilianCount = 0;

// Maximum number of civilians the player is
// allowed to kill before the mission ends
maxDeadCivilians = 3;

// FUNCTION: Record a civilian's death and
// alert the player of his actions
FNC_record_civilian_death =
{
    // Increase civilian death count and
    // calculate number of allowed kills left
    deadCivilianCount = deadCivilianCount + 1;
    _civilianKillsLeft = maxDeadCivilians - deadCivilianCount;

    // Check if player has reached the kill limit
    if(_civilianKillsLeft == 0) then {
        [] spawn FNC_reached_max_civilian_deaths;
    }

    // Display warning message if player
    // hasn't reach kill limit
    else {

        _msg = "%1 civilian";

        // Add an "s" to civilian if kills are greater than 1
        if(deadCivilianCount == 1) then {
            _msg = _msg + " has";
        }
        else {
            _msg = _msg + "s have";
        };

        _msg = _msg + " been killed. The mission is over if you kill %2 more!";

        // Output message to player
        hint format [_msg, deadCivilianCount, _civilianKillsLeft];
    }

};

// FUNCTION: Called when player has killed
// too many civilians. Display a message,
// and end the mission.
FNC_reached_max_civilian_deaths =
{
    hint "You killed too many innocent civilians!";
    sleep 5;
    endMission "END2";
};

// Add an event to every civilian's death
// that calls FNC_record_civilian_death
{
    if(side _x == Civilian && _x isKindOf "Man") then {
        _x addEventHandler ["killed", { [] spawn FNC_record_civilian_death }];
    };
} foreach allUnits;

Hope it helps.

So what I figured is I should just replace all the words 'civilians' with blufor and opfor and make 2 separate scripts (blufor.sqf and opfor.sqf and make both launch with nul = [] execvm "blufor.sqf";
nul = [] execvm "opfor.sqf";

I may have just derped here, I'm sure something is wrong.

Code:

// Current number of civilians
// the player has killed
deadBluforCount = 0;

// Maximum number of civilians the player is
// allowed to kill before the mission ends
maxDeadBlufor = 30;

// FUNCTION: Record a civilian's death and
// alert the player of his actions
FNC_record_blufor_death =
{
    // Increase civilian death count and
    // calculate number of allowed kills left
    deadBluforCount = deadBluforCount + 1;
   
    _bluforKillsLeft = maxDeadBlufor - deadBluforCount;
   

    // Check if player has reached the kill limit
    if(_bluforKillsLeft == 0) then {
        [] spawn FNC_reached_max_blufor_deaths;
   
    }

    // Display warning message if player
    // hasn't reach kill limit
    else {

        _msg = "%1 blufor";

        // Add an "s" to civilian if kills are greater than 1
        if(deadBluforCount == 1) then {
            _msg = _msg + " has";
        }
        else {
            _msg = _msg + "s have";
        };

        _msg = _msg + " been killed. The mission is over if you kill %2 more!";

        // Output message to player
        hint format [_msg, deadBluforCount, _bluforKillsLeft];
    }

};

// FUNCTION: Called when player has killed
// too many civilians. Display a message,
// and end the mission.
FNC_reached_max_blufor_deaths =
{
    hint "You have killed anough blufor soldiers!";
    sleep 5;
    endMission "END2";
};

// Add an event to every civilian's death
// that calls FNC_record_civilian_death
{
    if(side _x == Blufor && _x isKindOf "Man") then {
        _x addEventHandler ["killed", { [] spawn FNC_record_blufor_death }];
    };
} foreach allUnits;

never go full retard

Also, testing the map with these scripts made my fps drop to around 2 (not sure if scripts fault or w/e)

No you'll want one ini.sqf file. This is run automatically and does not need to be run. I'll try and write up some pseudo code underneath, but keep in mind I'm not testing this myself. I'm just going off my head and what I read in that script:

Screw it. I just wrote, debugged and tested the script you need. You just have to put the code below into a init.sqf file and place it in your mission folder next to the mission.sqm

Code:

//Number of blufor killed
numBluforKilled = 0;

//Number of Opfor killed
numOpforKilled = 0;

//Number of deaths on a team to lose the mission
numKillLimit = 30;

//FUNCTION: Record a Blufor death. Called by EventHandler created later.
FNC_Blufor_Killed =
{
   //Increase number of dead Blufor
   numBluforKilled = numBluforKilled + 1;
   
   //Calculate how many deaths are left
   _BluforDeathsRemaining = numKillLimit - numBluforKilled;
   
   //If Blufor has reached kill limit; Call the function to end the game with Blufor lost
   if(_BluforDeathsRemaining == 0) then {
      [] spawn FNC_Blufor_Limit_Reached;
   };
};

//FUNCTION: Called when Blufor has run out of lives. Ends the mission
FNC_Blufor_Limit_Reached =
{
   endMission "END1";
};

//FUNCTION: Record a Opfor death. Called by EventHandler created later.
FNC_Opfor_Killed =
{
   //Increase number of dead Blufor
   numOpforKilled = numOpforKilled + 1;
   
   //Calculate how many deaths are left
   _OpforDeathsRemaining = numKillLimit - numOpforKilled;
   
   //If Opfor has reached kill limit; Call the function to end the game with Opfor lost
   if(_OpforDeathsRemaining == 0) then {
      [] spawn FNC_Opfor_Limit_Reached;
   };
   
   //This is not necessary but good for debugging
   hint "Opfor was killed!";
};

//FUNCTION: Called when Opfor has run out of lives. Ends the mission
FNC_Opfor_Limit_Reached =
{
   endMission "END2";
};

//Here we add EventHandlers for Blufor and Opfor kills.
//This causes "FNC_Blufor_Killed" and "FNC_Opfor_Killed" to be called when a unit of that faction dies.
{
   if(side _x == Blufor && _x isKindOf "Man") then {
      _x addEventHandler ["killed", { [] spawn FNC_Blufor_Killed }];
   };
} foreach allUnits;

{
   if(side _x == Opfor && _x isKindOf "Man") then {
      _x addEventHandler ["killed", { [] spawn FNC_Opfor_Killed }];
   };
} foreach allUnits;

If you want respawn you'll have to figure that out for yourself. Just be aware you may need to add event handlers again.
I know there's a way to have different text for each END but I haven't looked into it. Take a look at how they did it in Arma 2, it's probably done the same way in A3.

I got respawn working, so that's that